[MineTweaker3] Учебное пособие: Thermal Expansion

[vandoom]

Поддерживаемые обработчики
Поддерживаются следующие обработчики:

• Магматический тигель
• Печь из красного камня
• Фитогенный инсолятор
• Измельчитель
• Лесопилка
• Индукционная плавильная установка
• Устройство для перемещения жидкости

ПРИМЕЧАНИЕ: Изменение теплового расширения с помощью Modtweaker иногда может потребовать перезапуска игры, особенно если вы удаляете рецепты. Иногда удаление рецептов даже не сработает.

В каждый из этих обработчиков можно добавлять или удалять рецепты:

//Магматический тигель
//InputRF, InputStack, OutputFluid
mods.thermalexpansion.Crucible.addRecipe(500000, <minecraft:dragon_egg>, <liquid:ender> * 8000);
//InputStack
mods.thermalexpansion.Crucible.removeRecipe(<minecraft:netherrack>);

//Печь из красного камня
//InputRF, InputStack, OutputStack
mods.thermalexpansion.Furnace.addRecipe(16000, <minecraft:obsidian>, <minecraft:netherrack>);
//InputStack //Recommended to sync with "furnace.remove();" function
mods.thermalexpansion.Furnace.removeRecipe(<minecraft:potato>);

//Фитогенный инсолятор
//InputRF, InputStack1, InputStack2, OutputStack1, OutputStack2, Chance
mods.thermalexpansion.Insolator.addRecipe(7200, <ThermalExpansion:material:516>, <minecraft:mycelium>, <minecraft:mycelium>, <minecraft:brown_mushroom>, 50);
mods.thermalexpansion.Insolator.addRecipe(9600, <ThermalExpansion:material:517>, <minecraft:mycelium>, <minecraft:mycelium> * 3, <minecraft:brown_mushroom>, 50);
//InputStack1, InputStack2
mods.thermalexpansion.Insolator.removeRecipe(<ThermalExpansion:material:516>, <minecraft:cactus>);
mods.thermalexpansion.Insolator.removeRecipe(<ThermalExpansion:material:517>, <minecraft:cactus>);

//Измельчитель
//InputRF, InputStack, OutputStack1, OutputStack2, Chance
mods.thermalexpansion.Pulverizer.addRecipe(3000, <minecraft:flint_and_steel>, <minecraft:flint>, <minecraft:iron_ingot>, 80);
//InputStack
mods.thermalexpansion.Pulverizer.removeRecipe(<minecraft:reeds>);

//Лесопилка
//InputRF, InputStack, OutputStack1, OutputStack2, Chance
mods.thermalexpansion.Sawmill.addRecipe(2400, <minecraft:ladder>, <minecraft:stick> * 5, <ThermalExpansion:material:512>, 100);
//InputStack
mods.thermalexpansion.Sawmill.removeRecipe(<minecraft:bed>);

//Индукционная плавильная установка
//InputRF, InputStack, InputStack2, OutputStack1, OutputStack2, Chance
mods.thermalexpansion.Smelter.addRecipe(800, <minecraft:dye:1>, <minecraft:sand>, <minecraft:stained_glass:14>, <ThermalExpansion:material:514>, 25);
//InputStack, InputStack1
mods.thermalexpansion.Smelter.removeRecipe(<minecraft:sand>, <minecraft:redstone_ore>);

//Устройство для перекачки жидкости
//InputRF, InputStack, OutputStack, InputFluid
mods.thermalexpansion.Transposer.addFillRecipe(2000, <minecraft:gunpowder>, <minecraft:tnt> * 2, <liquid:redstone> * 100);
//InputRF, InputStack, InputFluid, OutputStack, Chance
mods.thermalexpansion.Transposer.addExtractRecipe(2000, <minecraft:leaves>, <liquid:water> * 50, <minecraft:stick>, 100);
//InputStack, InputFluid
mods.thermalexpansion.Transposer.removeFillRecipe(<minecraft:glass_bottle>, <liquid:water>);
//InputStack
mods.thermalexpansion.Transposer.removeExtractRecipe(<minecraft:water_bucket>);

 

Поддерживаемые команды
Отпечатки хранятся в журнале minetweaker в каталоге minecraft.

/minetweaker thermalexpansion [HANDLER] - Outputs a list of all Thermal Expansion recipes