[MineTweaker3] Учебное пособие: Thaumcraft 4

vandoom · July 17, 2023

Поддерживаемые обработчики
Поддерживаются следующие обработчики:

Тайный верстак
Аспекты
Тигель
Вливание
Добыча
Деформировать
Исследование : Поддержка исследований Thaumcraft 4

ПРИМЕЧАНИЕ: Если вы хотите, чтобы рецепт, для которого требуется строка исследования, можно было создать сразу, используйте что-то вроде "АСПЕКТОВ", поскольку его не нужно разблокировать.

ПРИМЕЧАНИЕ: Некоторые рецепты Arcane Workbench нельзя удалить.

В каждый из этих обработчиков можно добавлять или удалять рецепты:

//Тайный верстак
//ResearchString, OutputStack, AspectString, InputArray
mods.thaumcraft.Arcane.addShaped("ASPECTS", <minecraft:stonebrick:3> * 4, "ordo 1", [[<minecraft:stonebrick>, <minecraft:stonebrick>, null], 
                                                                                     [<minecraft:stonebrick>, <minecraft:stonebrick>, null],
                                                                                     [null, null, null]]);
//ResearchString, OutputStack, AspectString, InputArray
mods.thaumcraft.Arcane.addShapeless("VOIDMETAL", <minecraft:ghast_tear>, "aqua 6, terra 6, perditio 6, ordo 6, aer 6, ignis 6", [<minecraft:ender_pearl>, <Thaumcraft:ItemResource:17>]);
//OutputStack
mods.thaumcraft.Arcane.removeRecipe(<Thaumcraft:ItemArcaneDoor>);
 
//Аспекты
//InputStack, AspectString
mods.thaumcraft.Aspects.add(<minecraft:saddle>, "motus 4");
//InputStack, AspectString
mods.thaumcraft.Aspects.set(<Thaumcraft:ItemBucketPure>, "aqua 4, metallum 8, vacous 1, sano 2, auram 2");
//InputStack, AspectString
mods.thaumcraft.Aspects.remove(<minecraft:glowstone_dust>, "lux 2");
//EntityString, AspectString
mods.thaumcraft.Aspects.addEntity("Skeleton", "lucrum 2, mortuus 1");
//EntityString, AspectString
mods.thaumcraft.Aspects.setEntity("Arrow", "telum 1");
//EntityString, AspectString
mods.thaumcraft.Aspects.removeEntity("Creeper", "ignis 2");

//Тигель
//ResearchString, OutputStack, InputStack, AspectString
mods.thaumcraft.Crucible.addRecipe("ENTROPICPROCESSING", <minecraft:dirt>, <minecraft:sapling>, "terra 2, perditio 4");
//OutputStack
mods.thaumcraft.Crucible.removeRecipe(<Thaumcraft:ItemResource:2>);

//Инфузия
//ResearchString, MainInputStack, InputArray, AspectString, OutputStack, InstabilityAmount
mods.thaumcraft.Infusion.addRecipe("NITOR", <Thaumcraft:ItemResource:1>, [<minecraft:fire_charge>, <Thaumcraft:ItemResource>, <minecraft:flint_and_steel>], "ignis 20, potentia 10, permutatio 12", <minecraft:fire> * 4, 5);
//OutputStack
mods.thaumcraft.Infusion.removeRecipe(<Thaumcraft:ItemAmuletVis:1>);
//ResearchString, EnchantmentID, InstabilityAmount, AspectString, InputArray,
mods.thaumcraft.Infusion.addEnchantment("XPBOOST", 45, 5, "victus 10, cognitio 8, vitreus 6",  [<minecraft:experience_bottle>, <minecraft:experience_bottle>, <minecraft:experience_bottle>, <Thaumcraft:ItemResource:14>]);
//EnchantmentID
mods.thaumcraft.Infusion.removeEnchant(1);

//Добыча
//InputStack, Weight
mods.thaumcraft.Loot.addCommonLoot(<Thaumcraft:ItemNugget:16>, 40);
mods.thaumcraft.Loot.addUncommonLoot(<Thaumcraft:ItemNugget:31>, 20);
mods.thaumcraft.Loot.addRareLoot(<Thaumcraft:ItemEldritchObject:3>, 5);
//InputStack
mods.thaumcraft.Loot.removeCommonLoot(<Thaumcraft:ItemBaubleBlanks>);
mods.thaumcraft.Loot.removeUncommonLoot(<Thaumcraft:ItemRingRunic>);
mods.thaumcraft.Loot.removeRareLoot(<minecraft:golden_apple:1>);

//Деформация
//ResearchString, WarpAmount
mods.thaumcraft.Warp.addToResearch("BATHSALTS", 5);
//InputStack, WarpAmount
mods.thaumcraft.Warp.addToItem(<Thaumcraft:ItemBathSalts>, 5);
//ResearchString
mods.thaumcraft.Warp.removeFromResearch("BOTTLETAINT");
//InputStack
mods.thaumcraft.Warp.removeFromItem(<Thaumcraft:ItemBottleTaint>);
//Overall Warp Removal
mods.thaumcraft.Warp.removeAll();
mods.thaumcraft.Warp.removeAllResearch();
mods.thaumcraft.Warp.removeAllItems();

Поддерживаемые команды
Родители хранятся в каталоге minetweaker для входа в minecraft.

/minetweaker aspectList - Outputs a list of Thaumcraft aspects
/minetweaker entities - Outputs a list of strings for Entities
/minetweaker research [CATEGORY] - Outputs a list of strings for Thaumcraft researches

BazZziliuS · July 18, 2023

Основы
Каждое исследование идентифицируется уникальной строкой, называемой его ключом. Общая схема именования заключается в том, что ключ должен быть написан заглавными буквами. Исключения из этой области составляют части палочки, которые, как правило, представлены в формате ROD_blah или CAP_blahblah.

Если вы хотите изменить существующее исследование, вам нужно знать его ключ. При добавлении нового рецепта Thaumcraft вам нужно будет указать ключ исследования в качестве первого аргумента. Рецепт будет недоступен для создания до тех пор, пока игрок не завершит исследование, которое идентифицируется по этому ключу.

Вы можете получить список исследовательских ключей в категории, используя внутриигровую команду /minetweaker research (категория), чтобы вывести все исследовательские ключи в этой категории в журнал MineTweaker. Например, /minetweaker research BASICS выведет все ключи исследования на вкладке "Основы".

Удаление исследований
Исследование может быть удалено с помощью метода remove Research(). Однако, если исследование было использовано в качестве предварительного условия для чего-либо, "Таумономикон" приведет к сбою игры при открытии вкладки этого исследования. Вы можете использовать orphanResearch(), чтобы обрезать все связи с исследованием, чтобы сделать его безопасным для удаления, или использовать clearPrereqs(), чтобы удалить предварительные условия из конкретных исследований.

Пример:
//ResearchKey mods.thaumcraft.Research.orphanResearch("ROD_greatwood"); mods.thaumcraft.Research.removeResearch("ROD_greatwood");

//ResearchKey
mods.thaumcraft.Research.orphanResearch("ROD_greatwood");
mods.thaumcraft.Research.removeResearch("ROD_greatwood");

Вкладки исследований
Каждая вкладка исследования также идентифицируется своей собственной уникальной строкой. Это важно знать, если вы хотите удалить вкладку или поместить в нее новое исследование.

Известные клавиши табуляции:

* BASICS
* THAUMATURGY
* ALCHEMY
* ARTIFICE
* GOLEMANCY
* FORBIDDEN (Apocrypha)
* TT_CATEGORY (Thaumic Tinkering)
* TX (Thaumic Esoterica)
* RAILCRAFT (Traheremagy)
* WITCHGADG (Witching Gadgets)

Вы можете получить список всех ключей категории исследований в игре, набрав /minetweaker research, чтобы вывести все ключи в журнал.

Удаление вкладок
Удаление вкладки "Исследование" также удаляет все исследования на вкладке, что может привести к сбоям, если они являются необходимыми для чего-либо. Используйте orphanResearch(), чтобы обрезать все связи с исследователями на вкладке, переместить все исследования на другую вкладку или придерживаться удаления небольших вкладок, в которых ничего нет, например, Traheremagy.

Пример:

//TabKey
mods.thaumcraft.Research.removeTab("RAILCRAFT");

Создание вкладок
Для создания вкладки "Исследование" требуется указать спрайт для значка вкладки. Вам понадобится домен и путь к файлу для текстуры. Вам также нужно будет создать локализацию для названия вкладки либо с помощью пакета ресурсов, либо с помощью Modtweaker localization changer. Ключом локализации всегда будет "tc.research_category.", за которым следует клавиша tab.

Например, если вы хотели вкладку со значком мозга зомби из Thaumcraft 4:

//TabKey, Domain, Path
mods.thaumcraft.Research.addTab("DEMENTIA", "thaumcraft", "textures/items/brain.png");
game.setLocalization("en_US", "tc.research_category.DEMENTIA", "Dementia");

Вкладки также можно создавать с пользовательским фоном, если вы предоставите текстуру:

//TabKey, IconDomain, IconPath, BackgroundDomain, BackgroundPath
mods.thaumcraft.Research.addTab("AHPYRCOPA", "forbidden", "textures/items/spork.png", "forbidden", "textures/misc/runecircle.png");
game.setLocalization("en_US", "tc.research_category.AHPYRCOPA", "Not Apocrypha");

Создание исследовательской
Исследование создается с помощью уникального ключа, клавиши вкладки "Исследование", списка аспектов, координат, рейтинга сложности и либо пути к текстуре, либо набора элементов, чтобы придать ему значок. Как и при создании вкладки "Исследование", для создания нового исследования требуется новая локализация.

Если исследование добавлено через ModTweaker, его название локализуется как "tc.research_name.", за которым следует ключ исследования. Его всплывающая подсказка локализована как "tc.research_text". За ней следует ключ.

Аспекты вводятся в виде одной строки со списком аспектов и значений, разделенных запятыми. Если вы планируете выполнить автоматическую разблокировку исследования, можно оставить его без аспектов и просто ввести null в качестве списка аспектов.

Координаты сторон отличаются от стандартных математических координат. Уменьшение Y продвигает исследование вверх, в то время как увеличение Y продвигает его вниз. Увеличение X сдвигает исследование еще дальше вправо, как и следовало ожидать.

Пример:

//ResearchKey, TabKey, AspectList, X, Y, Complexity, ItemStack 
//Make sure that the X and Y coordinates of your research doesn't conflict with other researches
mods.thaumcraft.Research.addResearch("WTFPLANTS", "BASICS", "lucrum 100, alienis 200", 1, 0, 8, <minecraft:sapling>);
game.setLocalization("en_US", "tc.research_name.WTFPLANTS", "Trees!");
game.setLocalization("en_US", "tc.research_text.WTFPLANTS", "[MT] Science just doesn't know!");

Добавление страниц в исследование
Простого создания базы исследований недостаточно. Базовое исследование начинается без страниц и приводит к сбою игры, если вы попытаетесь его открыть. Как только исследование будет создано, вы можете использовать addPage() для добавления новых страниц. Просто введя ключ и ключ локализации, вы добавите обычную текстовую страницу, которую можно заполнить локализацией.

Пример:

//ResearchKey, LocalizationKey
mods.thaumcraft.Research.addPage("WTFPLANTS", "derp.research_page.WTFPLANTS");
game.setLocalization("en_US", "derp.research_page.WTFPLANTS", "Plants! What are they?<BR>The Thaumometer doesn't know!");

При локализации текста для исследовательских страниц можно использовать следующую разметку:

# Special formatting codes:
# <BR> or <BR/>         Paragraph break (<BR/> is included for people using XML for their localization)
# <LINE> or <LINE/>     Insert a fancy linebreak between sections of text.
# <IMG>...</IMG>  Insert a centered image into text. Parameters are separated by ':' and are:
#                    - mod resource location name
#                    - png file location (assumed to be a 256x256 texture, a sub-image will be grabbed from this png as specified below)
#                    - x location of sub-image in png
#                    - y location of sub-image in png
#                    - x size of sub-image (255 if full x size of png must be used)
#                    - y size of sub-image (255 if full y size of png must be used)
#                    - scaling - 1.0 for normal 256x256 images, or smaller for proportionately smaller .png files (a 16x16 image will be 0.0625)   
#               Examples: 
#                   <IMG>thaumcraft:textures/gui/gui_researchbook.png:24:184:96:4:1.0</IMG>   <-- line break image as used in <LINE> above
#                   <IMG>thaumcraft:textures/items/alumentum.png:0:0:255:255:0.0625</IMG>     <-- alumentum item icon

Для добавления страниц с рецептами можно использовать следующие методы. Каждый из них принимает ключ и ItemStack в качестве аргумента и добавляет страницу, отображающую первый рецепт для этого элемента, который он может найти. Обязательно добавьте рецепт какого-либо блюда, прежде чем пытаться добавить страницу с рецептом.

//Adds a normal crafting table recipe page
mods.thaumcraft.Research.addCraftingPage("WTFPLANTS", <minecraft:planks>);
//Adds an arcane crafting table recipe page
mods.thaumcraft.Research.addArcanePage("WTFPLANTS", <Thaumcraft:WandRod>);
//Adds a crucible recipe page
mods.thaumcraft.Research.addCruciblePage("WTFPLANTS", <Thaumcraft:ItemResource:1>);
//Adds an infusion recipe page
mods.thaumcraft.Research.addInfusionPage("WTFPLANTS", <Thaumcraft:WandRod:2>);

Страницы зачарования инфузии можно добавить, указав ключ и идентификатор зачарования.

mods.thaumcraft.Research.addEnchantmentPage("WTFPLANTS", 18);

Убедитесь, что в рецепте используется ключ этого исследования в качестве собственного ключа, иначе рецепт на самом деле нельзя будет создать, когда исследование будет разблокировано.

Объединяющие исследования
Исследование выявило три типа связей: родители, Скрытые родители и братья и сестры.

Родители - это обязательное условие для проведения исследований, которое вам необходимо разблокировать, прежде чем вы сможете приступить к конкретному исследованию. Например, родительскими элементами ROD_silverwood являются INFUSION и ROD_greatwood. Вы не можете исследовать палочку из Серебристого дерева, предварительно не изучив настой и палочку из Грейтвуда. Если исследование находится на той же странице, что и его родители, "Таумономикон" проведет линию от родителя к дочернему элементу, чтобы указать, что к чему ведет.

Скрытые родители похожи на родителей, за исключением того, что "Таумономикон" не проводит черту между ними, даже если они находятся на одной странице. Используйте это, если вы пытаетесь уменьшить беспорядок на вкладке "Исследование".

Чтобы добавить родителей или скрытых родителей в исследование:

//ResearchKey, Parent, Hidden?
mods.thaumcraft.Research.addPrereq("WTFPLANTS", "ICHOR", false);

Братья и сестры - это исследования, которые автоматически разблокируются при выполнении конкретного исследования. Например, у DISTILL ESSENTIAL есть родственная JARLABEL. Когда вы исследуете процесс дистилляции Essentia, вы автоматически открываете раздел "Исследование этикеток банок". Когда братья и сестры находятся на одной вкладке, Thaumonomicon проведет границу между ними.

Чтобы добавить родственника в исследование:

//ResearchKey, Sibling
mods.thaumcraft.Research.addSibling("WTFPLANTS, "ZOMGSAPLINGS");

Чтобы изменить родителей или братьев и сестер для существующего исследования, вам нужно будет использовать следующие команды, чтобы очистить эти значения, а затем добавить свои собственные.

//ResearchKey
mods.thaumcraft.Research.clearPrereqs("ICHOR");
mods.thaumcraft.Research.clearSiblings("WTFPLANTS");

Модифицирующее исследование
Существует множество тегов и дополнительных команд для добавления дополнительных функций в созданное вами исследование или изменения существующих.

Вот некоторые стандартные исследовательские теги:

КРУГЛЫЙ - у исследования есть круглый значок в "Таумономиконе". Обычно для исследований без рецепта или исследований с автоматической разблокировкой.
SPIKY - Research имеет шипы вокруг своего значка. Как правило, для указания на важность исследования.
ЗАГЛУШКА - Исследование не может быть исследовано игроком. Как правило, для исследований, которые разблокируются другими способами, такими как братья и сестры или автоматическая разблокировка.
ВТОРИЧНОЕ исследование имеет восьмиугольный значок в "Таумономиконе" и покупается за очки вместо "исследовано".
ВИРТУАЛЬНОЕ исследование на самом деле не существует и не может быть исследовано. Используется в качестве "родительского" исследования, которое обычно не может быть разблокировано.
АВТОМАТИЧЕСКАЯ РАЗБЛОКИРОВКА - Исследование начинается с уже разблокированного приложения.
СКРЫТОЕ исследование не появляется в "Таумономиконе" до тех пор, пока не будут завершены его родительские исследования. Используется для большинства исследований по умолчанию.

Они могут быть установлены с помощью следующих команд:

//ResearchKey, Value
mods.thaumcraft.Research.setRound("WTFPLANTS", true);
mods.thaumcraft.Research.setSpikey("WTFPLANTS", true);
mods.thaumcraft.Research.setStub("WTFPLANTS", true);
mods.thaumcraft.Research.setSecondary("WTFPLANTS", true);
mods.thaumcraft.Research.setVirtual("WTFPLANTS", true);
mods.thaumcraft.Research.setAutoUnlock("ASPECTS", false);
mods.thaumcraft.Research.setConcealed("WTFPLANTS", true);

Вы можете изменить аспекты существующего исследования. Аспекты определяют, какие и сколько исследовательских баллов вам нужно для приобретения исследования в режиме простого исследования или если это вторичное исследование. Они также определяют, какие аспекты вам нужно будет подключить во время исследовательской мини-игры для второстепенных исследований или в режиме жесткого исследования.

//ResearchKey, Aspects
mods.thaumcraft.Research.setAspects("WTFPLANTS", "lucrum 39, perditio 96, potentia 100");

Сложность - это то, что определяет уровень сложности исследования. Чем выше уровень сложности исследования, тем более раздражающим оно будет в исследовательской мини-игре.

//ResearchKey, Complexity
mods.thaumcraft.Research.setComplexity("WTFPLANTS", 16);

Если вы пытаетесь изменить страницы для существующего исследования, вам сначала нужно очистить исследование от страниц с помощью этого:

//ResearchKey
mods.thaumcraft.Research.clearPages("WTFPLANTS");

Как только вы очистите все страницы, вы можете вручную добавить страницы обратно в любом формате, который вы хотите.

Обычно, когда вы меняете рецепт Thaumcraft, на странице поиска по нему по-прежнему отображается оригинальный рецепт. Вы можете изменить это вручную, очистив все страницы и добавив их обратно, или вы можете использовать это, чтобы попытаться принудительно обновить рецепт:

//ResearchKey
mods.thaumcraft.Research.refreshResearchRecipe("WTFPLANTS");

Обновление результатов исследования сработает только в том случае, если рецепт остается того же типа (тайный рабочий стол, настой и т.д.). В противном случае вам нужно будет очистить страницы исследований и добавить их обратно с новым типом рецепта.

Наконец, если вы хотите переместить существующее исследование в другое место и / или на другую вкладку, вы можете воспользоваться этим:

//ResearchKey, DestinationCategory, X, Y
mods.thaumcraft.Research.moveResearch("INFERNALFURNACE", "FORBIDDEN", 1, 0);

Sign In

[MineTweaker3] Учебное пособие: Thaumcraft 4

Recommended Posts

vandoom

Link to comment

Share on other sites

BazZziliuS

Link to comment

Share on other sites

Join the conversation

Форум

Активность