[MineTweaker3] Учебное пособие: Mekanism

[vandoom]

Поддерживаемые обработчики
Поддерживаются следующие обработчики:

• Химический кристаллизатор
• Камера химического растворения
• Химический инфузор
• Камера для впрыска химических веществ
• Химический окислитель
• Химическая мойка
• Комбайн
• Осмиевый компрессор
• Дробилка
• Плавильный завод, работающий под напряжением
• Камера обогащения
• Металлургический заварочный аппарат
• Камера очистки
• Реакционная камера под давлением
• Прецизионная лесопилка
• Электролитический конденсатор
• Солнечное испарение
• Активация солнечными нейтронами

В каждый из этих обработчиков можно добавлять или удалять рецепты:

//Химический кристаллизатор
//InputGas, OutputStack
mods.mekanism.chemical.Crystallizer.addRecipe(<gas:water>, <minecraft:ice>);
//OutputStack, InputGas
mods.mekanism.chemical.Crystallizer.removeRecipe(<Mekanism:OtherDust:4>, <gas:lithium>);

//Камера химического растворения
//InputStack, OutputGas
mods.mekanism.chemical.Dissolution.addRecipe(<minecraft:ice>, <gas:water>);
//OutputGas, InputStack
mods.mekanism.chemical.Dissolution.removeRecipe(<gas:osmium>, <Mekanism:OreBlock>);

//Химический инфузор
//InputGas1, InputGas2, OutputGas
mods.mekanism.chemical.Infuser.addRecipe(<gas:water>, <gas:deuterium>, <gas:steam>);
//OutputGas, InputGas1, InputGas2
mods.mekanism.chemical.Infuser.removeRecipe(<gas:hydrogenchloride>, <gas:hydrogen>, <gas:chlorine>);

//Камера для впрыска химических веществ
//Входной пакет, входной газ, выходной пакет
//InputGas only accepts "<gas:sulfuricAcid>", "<gas:water>" or "<gas:hydrogenChloride>"
mods.mekanism.chemical.Injection.addRecipe(<minecraft:hardened_clay:1>, <gas:water>, <minecraft:clay>);
//OutputStack, InputStack, InputGas
mods.mekanism.chemical.Injection.removeRecipe(<Mekanism:Shard:2>, <Mekanism:OreBlock>, <gas:hydrogenchloride>);

//Химический окислитель
//InputStack, OutputGas
mods.mekanism.chemical.Oxidizer.addRecipe(<Mekanism:Dust:2>, <gas:cleanOsmium>);
//OutputGas, InputStack
mods.mekanism.chemical.Oxidizer.removeRecipe(<gas:brine>, <Mekanism:Salt>);

//Химическая мойка
//InputGas, OutputGas
mods.mekanism.chemical.Washer.addRecipe(<gas:steam>, <gas:water>);
//OutputGas, InputGas
mods.mekanism.chemical.Washer.removeRecipe(<gas:cleanLead>, <gas:lead>);

//Комбайн
//InputStack, InputGas, OutputStack
mods.mekanism.Combiner.addRecipe(<minecraft:stone> * 4, <gas:liquidStone>, <minecraft:stonebrick>);
//OutputStack, InputStack, InputGas
mods.mekanism.Combiner.removeRecipe(<minecraft:gravel>, <minecraft:flint>, <gas:liquidStone>);

//Осмиевый компрессор
//InputStack, InputGas, OutputStack
mods.mekanism.Compressor.addRecipe(<Mekanism:BasicBlock:3>, <gas:liquidOsmium>, <minecraft:bedrock>);
//OutputStack, InputStack, InputGas
mods.mekanism.Compressor.removeRecipe(<Mekanism:Ingot>, <Mekanism:OtherDust:5>, <gas:liquidOsmium>);

//Дробилка
//InputStack, OutputStack
mods.mekanism.Crusher.addRecipe(<minecraft:double_plant:4>, <minecraft:dye:1> * 5);
//OutputStack, InputStack
mods.mekanism.Crusher.removeRecipe(<minecraft:sand>, <minecraft:gravel>);

//Плавильный завод под напряжением
//InputStack, OutputStack
mods.mekanism.Smelter.addRecipe(<minecraft:tallgrass:1>, <minecraft:deadbush>);
//InputStack, OutputStack
mods.mekanism.Smelter.removeRecipe(<minecraft:sand>, <minecraft:glass>);

//Обогатительная камера
//InputStack, OutputStack
mods.mekanism.Enrichment.addRecipe(<minecraft:coal_block>, <Mekanism:CompressedCarbon> * 9);
//InputStack, OutputStack
mods.mekanism.Enrichment.removeRecipe(<minecraft:mossy_cobblestone>, <minecraft:cobblestone>);

//Металлургический заварочный аппарат
//InfusionString, InputInfusion, InputStack, OutputStack 
//InfusionString = CARBON;TIN;DIAMOND;REDSTONE;FUNGI;BIO;OBSIDIAN
mods.mekanism.Infuser.addRecipe("OBSIDIAN", 20, <minecraft:coal_block>, <minecraft:obsidian>);
//OutputStack, InputStack, InfusionString
mods.mekanism.Infuser.removeRecipe(<minecraft:mycelium>);

//Камера очистки
//InputStack, InputGas, OutputStack
mods.mekanism.Purification.addRecipe(<minecraft:wool:1>, <gas:hydrogenchloride>, <minecraft:wool>);
//OutputStack, InputStack, InputGas
mods.mekanism.Purification.removeRecipe(<Mekanism:Clump:2>, <Mekanism:Shard:2>, <gas:oxygen>);

//Реакционная камера под давлением
//InputStack, InputFluid, InputGas, OutputStack, OutputGas, InputRF, Time in Ticks
mods.mekanism.Reaction.addRecipe(<Mekanism:Polyethene>, <liquid:ethene>, <gas:oxygen>, <Mekanism:Polyethene> * 8, <gas:oxygen>, 50000, 2000);
//OutputStack, OutputGas, InputStack, InputFluid, InputGas
mods.mekanism.Reaction.removeRecipe(<Mekanism:Substrate>, <gas:ethene>, <Mekanism:BioFuel>, <liquid:water>, <gas:hydrogen>);

//Прецизионная лесопилка
//InputStack, OutputStack1, OutputStack2, Chance
mods.mekanism.Sawmill.addRecipe(<minecraft:bow>, <minecraft:stick> * 3, <minecraft:string> * 3, 0.5);
//InputStack, OutputStack1, OutputStack2
mods.mekanism.Sawmill.removeRecipe(<minecraft:bed>, <minecraft:planks>, <minecraft:wool>);

//Электролитический сепаратор
//InputFluid, InputRF, OutputGas1, OutputGas2
mods.mekanism.Separator.addRecipe(<liquid:fusionfueldt>, 5000, <gas:deuterium>, <gas:tritium>);
//InputFluid, OutputGas1, OutputGas2
mods.mekanism.Separator.removeRecipe(<liquid:heavywater>, <gas:deuterium>, <gas:oxygen>);

//Солнечное испарение
//InputFluid, OutputFluid
mods.mekanism.SolarEvaporation.addRecipe(<liquid:lava>, <liquid:fusionfueldt>);
//InputFluid, OutputFluid
mods.mekanism.SolarEvaporation.removeRecipe(<liquid:water>, <liquid:brine>);

//Активатор солнечных нейтронов
//InputGas, OutputGas
mods.mekanism.SolarNeutronActivator.addRecipe(<gas:liquidStone>, <gas:liquidOsmium>);
//InputGas, OutputGas
mods.mekanism.SolarNeutronActivator.removeRecipe(<gas:lithium>, <gas:tritium>);

 

Поддерживаемые команды
Отпечатки хранятся в журнале minetweaker в каталоге minecraft.

/minetweaker mekanism [HANDLER] - Outputs a list of all Mekansm recipes
/minetweaker gases - Outputs a list of gases