[MineTweaker3] Учебное пособие: MineFactory Reloaded

[vandoom]

Автоматический спавнер
Можно добавлять и удалять объекты в черный список, если вы знаете имя класса:

import mods.mfr.AutoSpawner;

# Замените желаемое имя класса сущности
AutoSpawner.addBlacklist("mods.natura.entity.NitroCreeper");
AutoSpawner.removeBlacklist("mods.natura.entity.NitroCreeper");

Данное имя класса сущности должно быть допустимым живым объектом. Если вы хотите знать, какие имена сущностей существуют в игре, используйте команду /mt entities, чтобы сгенерировать список для вас.

 

Жнец
Новые блоки могут быть добавлены в комбайн для сбора урожая:

import mods.mfr.Harvester;

//вишневое дерево - имейте в виду, что журналы имеют разное мета-значение при разной ориентации
// use /mt blockinfo to check the correct meta values for the leaves
Harvester.addHarvestable(<BiomesOPlenty:logs1:*>,"tree");
Harvester.addHarvestable(<BiomesOPlenty:leaves3:9>,"treeLeaf");

//magical tree
Harvester.addHarvestable(<BiomesOPlenty:logs2:*>,"tree");
Harvester.addHarvestable(<BiomesOPlenty:leaves1:10>, "treeLeaf");

Второй аргумент - это тип, пригодный для сбора урожая. "дерево" будет следовать алгоритму MFR для обрезки деревьев, сначала срезая листья. "treeLeaf" используется для обозначения листьев. "обычный" используется для одиночных блоков, а "столбчатый" - для таких растений, как кактусы и тростник. Термин "treeFlipped" предположительно используется для обозначения деревьев, растущих вверх ногами. Естественный, кто-нибудь?

Обычно комбайн генерирует предметы, которые выпадают, разбивая блоки. Другие элементы можно удалить, указав их:

Harvester.addHarvestable(<BiomesOPlenty:logs2:*>, <minecraft:stick> * 4, "tree");
Harvester.addHarvestable(<BiomesOPlenty:logs1:*>, [<minecraft:stick> * 4, <BiomesOPlenty:woodenDoubleSlab1:1> % 25], "tree");

Если указаны пользовательские элементы, отбрасывания по умолчанию игнорируются.

 

Шахтный лазер
С помощью горного лазера можно добавлять и удалять руду:

import mods.mfr.MiningLaser;

MiningLaser.addOre(<tile.stone>.weight(1000)); # Let's be an asshole and make it generate stone most of the time
MiningLaser.addOre((<tile.stone> * 2).withTag({Display: {Name: "Funny Stone"}}).weight(1000)); # works with stack sizes and tags
MiningLaser.removeOre(<tile.oreIron>); # can use ore dictionary entries, too (will remove all matching items)

MiningLaser.addPreferredOre(1, <tile.oreIron>); # color codes are the same as the wool meta values
MiningLaser.removePreferredOre(1, <tile.oreIron>);

Чтобы узнать, какие лазерные руды существуют, используйте команду /mt mfr laserores. Он также печатает предпочитаемый лазер или список, чтобы просмотреть цветовые предпочтения лазера.

 

Сеялка
Вы можете определить новые элементы для посадки в сеялке:

import mods.mfr.Planter;

Planter.addPlantable(<BiomesOPlenty:saplings:10>);

(Доступно больше функций, но они не завершены)

 

Каучуковое дерево
Ваш любимый мод worldgen не создает каучуковые деревья в нужном биоме? Исправить это легко:

import mods.mfr.RubberTree;

RubberTree.addBiome("SuperXLBiome");
RubberTree.removeBiome("SuperXLBiome");

Чтобы найти список названий биомов, используйте /mt biomes !

 

Шламовый котел
Капли можно добавлять и удалять:

import mods.mfr.SludgeBoiler;

SludgeBoiler.addDrop(<minecraft:stick> * 16);
SludgeBoiler.addDrop(<TConstruct:CraftedSoil:4>.weight(10));
SludgeBoiler.removeDrop(<minecraft:dirt:1>);

Используйте /mt mfr sludge drops, чтобы получить список капель осадка, сгенерированный в minetweaker.log.